        .Z80

        LD HL,OBJ            ; Организация псевдо-ROM
        LD DE,04000H         ; в 1-й странице слота 3-2
        LD BC,80H            ;
        LDIR                 ;
        LD HL,START          ; Создание структуры страниц
        LD DE,09000H         ; должно происходить в "верхних"
        LD BC,OBJ-START      ; адресах
        LDIR                 ;
        JP 9000H             ;
START:  DI                   ;
        LD A,0FCH            ; 1-я страница - BASIC BIOS
        OUT (0A8H),A         ; 2-я страница из слота 3-2
        LD A,0A8H            ; 3-я страница из слота 3-2
        LD (0FFFFH),A        ; 4-я страница из слота 3-2
        EI                   ;
        LD HL,(4002H)        ;
        JP (HL)              ; Переход на начало основной программы
OBJ:                         ;
        .PHASE 4000H         ;
        DB 'AB'              ; Идентификатор ПЗУ
        DW NACH              ; Адрес начала программы
        DW 0                 ; Зарезервированы 12 байтов
        DW 0                 ;
        DW 0                 ;
        DW 0                 ;
        DW 0                 ;
        DW 0                 ;
NACH:   XOR A                ; 
        CALL 00C3H           ; Очистка экрана
        CALL 00CCH           ; Выключение функциальных клавиш
        DI                   ;
        IM 1                 ; Установка 1-го режима прерываний:
        LD A,0C3H            ; - сохраняется программный счетчик в стеке;
        LD (0FD9AH),A        ; - переход по адресу 038H, где  происходит
        LD HL,WORK           ;   обращение  к  адресам  0FD9AH  и 0FD9FH
        LD (0FD9BH),HL       ;   с частотой 60 Гц.Любой из адресов можно
        EI                   ;   использовать для обработки прерываний
LABEL:  JR LABEL             ;
WORK:                        ;
        LD A,7               ; Это и есть подпрограмма, генерирующая
        OUT (0A0H),A         ; звонок-сигнал!
        LD A,10111110B       ;
        OUT (0A1H),A         ;
        LD A,8               ;
        OUT (0A0H),A         ;
        LD A,10H             ;
        OUT (0A1H),A         ;
        LD A,11              ;
        OUT (0A0H),A         ;
        LD A,100             ;
        OUT (0A1H),A         ;
        LD A,12              ;
        OUT (0A0H),A         ;
        LD A,0               ;
        OUT (0A1H),A         ;
        LD A,13              ;
        OUT (0A0H),A         ;
        LD A,1               ;
        OUT (0A1H),A         ;
        RET                  ;
        .DEPHASE             ;
        END                  ;
