        CALL N_DRIVE       ; Проверка существования устройства
        LD   DE,0100H      ; Установка адреса обмена
        LD   C,1AH         ;
        CALL 5             ;
        LD   DE,005CH      ; Открытие файла, FCB которого
        LD   C,0FH         ; находится по адресу 5CH.
        CALL 5             ; Это - стандарт для MSXDOS.SYS
        OR   A             ;
        LD   DE,FILE_NO    ; Если файл отсутствует, то сообщение
        JP   NZ,E_EXIT     ; и выход.
        LD   HL,0          ;
        LD   (007DH),HL    ; Подготовка FCB для считывания
        LD   (007FH),HL    ; записей из файла.
        INC  HL            ;
        LD   (006AH),HL    ;
LBL2:   LD   DE,005CH      ; Считывание происходит по 1,5 Кб
        LD   HL,0600H      ; пока не кончится файл,
        LD   C,27H         ; и печать на экран дисплея
        CALL 5             ; содержимого файла
        LD   A,L           ;
        OR   H             ;
        JP   Z,EXIT        ;
        LD   DE,0100H      ; Программа печати на консоль
LBL1:   LD   A,(DE)        ;
        INC  DE            ;
        CP   1AH           ; 1АH - код конца файла
        JP   Z,EXIT        ;
        CALL PEN           ;
        DEC  HL            ;
        LD   A,L           ;
        OR   H             ;
        JR   NZ,LBL1       ;
        JR   LBL2          ;
                           ;
N_DRIVE:                   ;
        LD   A,(005CH)     ; Подпрограмма проверки существования
        INC  A             ; устройства. Если устройство указано
        RET  NZ            ; неверно, то выход с сообщением
        POP  DE            ;
        LD   DE,SPECIF     ;
        JP   E_EXIT        ;
PEN:    PUSH HL            ; Подпрограмма вывода символа на консоль
        PUSH DE            ;
        PUSH BC            ;
        PUSH AF            ;
        LD   E,A           ;
        LD   C,2           ;
        CALL 5             ;
        POP  AF            ;
        POP  BC            ;
        POP  DE            ;
        POP  HL            ;
        RET                ;
EXIT:   RET                ;
E_EXIT: LD   C,9           ;
        JP   5             ;
FILE_NO:DEFM "File not found$"
SPECIF: DEFM "Invalid drive specification$"
