Манипулятор мышь для MSX.

Поставлялась в составе Ямаха КУВТ 2.

Фото сделал Артем Читайло

Может работать в режиме джойстик.

Оригинальная документация

Олег Шамшура, 1990.
Оригинал

Try corporation
Инструкция
Параллельная мышь
MS-10 ( 200 count )

• Введение
  • Спасибо за покупку мыши MS-10.
  • MS-10 — это устройство ввода с функциями мыши и джойстика.
  • Оно освободит Вас от работы с клавиатурой, сделает игры с компьютером более реалистичными и приятными, а также обеспечит работу с другим программным обеспечением.
  • Перед использованием внимательно прочтите эту инструкцию.

1. Совместимые устройства
   • Мышь совместима с любым компьютером серии MSX. Чтобы определить, к какому порту ее подключать, обратитесь к описанию соответствующей программы.
   • С программным обеспечением, рассчитанным на джойстик, можно работать в «режиме джойстика».
2. Наименования частей

   	ВИД СВЕРХУ
   
        разъем ┌───┐
               └┐ ┌┘
                 H
                 H			   ВИД СНИЗУ
                 H
          ┌─────┴─┴─────┐         ┌──────────────┐
          ├─┬───┬─┬───┬─┤         │ 0          0 │
          │ │   │ │   │ │         │              │
          │ │   │ │   │ │         │              │
          │ └───┘ └───┘ │         │  съемная крышка
    левая кнопка   правая кнопка  │   ┌──────┐   │
          │             │         │   │  __  │   │
          │             │         │   │ (  ) шарик
     корпус             │         │   │  ~~  │   │
          │             │         │ 0 └──────┘ 0 │
          └─────────────┘         └──────────────┘

3. Работа с мышью
   • Выньте предохранительную упаковку, вставленную между шариком и съемной крышкой.
   • Вставьте разъем MS-10 в соответствующий порт.
4. Обслуживание
   • Время от времени протирайте шарик и колесики внутри корпуса. Съемная крышка легко вынимается поворотом влево.
   • Не вскрывайте корпус и не разбирайте внутренних частей. В противном случае Вы лишаетесь гарантии.
5. Режим «мышь»
   • Если для работы с программой нужна мышь, используйте этот режим.
   • Проверьте скольжение мыши в четырех направлениях: вперед, назад, влево и вправо.
     • а) В MSX1 нельзя использовать команды PAD & STRIG. В этом случае необходимо составить собственную программу, соответствующую команде PAD, обратившись к следующему примеру:
       mouse1.bas

       10 REM *** ПРИМЕР ДЛЯ MSX1 ***
       20 SCREEN 2:CLS
       30 CLEAR 256,&HDFFF
       40 FOR N=0 TO 127
       50 READ M$:M=VAL("&H"+M$)
       60 POKE &HE000+N,M
       70 NEXT N
       80 C=15
       90 XX=127:YY=96
       100 DEFUSR0=&HE000
       110 ON INTERVAL=4 GOSUB 150
       120 INTERVAL ON
       130 PSET (XX,YY),C
       140 GOTO 140
       150 A=USR0(0)
       160 Y=PEEK(&HE200):IF Y>127 THEN Y=Y-256
       170 X=PEEK(&HE201):IF X>127 THEN X=X-256
       180 XL=XX:YL=YY
       190 XX=XX+X:IF XX<0 THEN XX=0 ELSE IF XX>255 THEN XX=255
       200 YY=YY+Y:IF YY<0 THEN YY=0 ELSE IF YY>191 THEN YY=191
       210 IF STRIG (1) THEN LINE (XL,YL)-(XX,YY),C ELSE PRESET STEP (0,0)
       220 IF STRIG (3) THEN CLS:GOTO 90
       230 RETURN 130
       240 DATA 3E,0F,CD,96,00,E6,8F,F6,30,5F,00,3E,0F,CD,93,00
       250 DATA 06,1A,10,FE,00,3E,0E,CD,96,00,57,7B,E6,8F,06,02
       260 DATA 5F,10,FE,00,3E,0F,CD,93,00,3E,0F,A2,07,07,07,07
       270 DATA 4F,06,07,10,FE,00,3E,0E,CD,96,00,57,7B,F6,30,5F
       280 DATA 00,3E,0F,CD,93,00,3E,0F,A2,B1,67,06,07,10,FE,00
       290 DATA 3E,0E,CD,96,00,57,7B,E6,8F,5F,00,3E,0F,CD,93,00
       300 DATA 3E,0F,A2,07,07,07,07,06,07,4F,10,FE,00,3E,0E,00
       310 DATA CD,96,00,57,3E,0F,A2,B1,6F,22,00,E2,C9,00,00,00

     • б) PAD & STRIG могут использоваться на MSX2 и MSX2+
       mouse2.bas

       10 REM *** ПРИМЕР ТОЛЬКО ДЛЯ MSX2 ***
       20 SCREEN 5:CLS
       30 C=15
       40 XX=127:YY=96
       50 PSET (XX,YY),C
       60 XL=XX:YL=YY
       70 XX=XX+X:IF XX<0 THEN XX=0 ELSE IF XX>255 THEN XX=255
       80 YY=YY+Y:IF YY<0 THEN YY=0 ELSE IF YY>211 THEN YY=211
       90 Z=PAD (12)
       100 X=PAD (13)
       110 Y=PAD (14)
       120 IF STRIG (1) THEN LINE (XL,YL)-(XX,YY),C ELSE PRESET STEP (0,0)
       130 IF STRIG (3) THEN CLS:GOTO 40
       140 GOTO 50
       150 END

6. Режим «джойстик»
   • Если для работы с программой необходим джойстик, Вы можете использовать этот режим.
   • Проверьте скольжение мыши в восьми направлениях: вперед, назад, влево, вправо и в промежуточных.
   • Для перехода в режим «джойстик»: выключите питание компьютера, нажмите и удерживайте левую кнопку MS-10, после чего включите питание. Не отпускайте кнопку, пока MSX BASIC не стартовал.
   • В этом режиме используются команды STICK & STRIG.
     mouse3.bas

     10 REM *** ПРИМЕР ДЛЯ ДЖОЙСТИКА ***
     20 SCREEN 5:CLS
     30 C=15
     40 XX=127:YY=96
     50 PSET (XX,YY),C
     60 ON STICK (1) GOSUB 100,110,120,130,140,150,160,170
     70 IF STRIG (1) THEN PSET (X,Y),C ELSE PRESET STEP (0,0)
     80 IF STRIG (3) THEN CLS:GOTO 40
     90 GOTO 50
     100 Y=Y-2:RETURN
     110 X=X+2:Y=Y-2:RETURN
     120 X=X+2:RETURN
     130 X=X+2:Y=Y+2:RETURN
     140 Y=Y+2:RETURN
     150 X=X-2:Y=Y+2:RETURN
     160 X=X-2:RETURN
     170 X=X-2:Y=Y-2:RETURN
     180 END

7. Спецификации

   1	Разрешающая способность	200 отсчетов на дюйм
   2	Скорость перемещения	50 мм / сек
   3	Назначение контактов	N 1 2 3 4 5 6 7 8 9 MOUSE DATA0 DATA1 DATA2 DATA3 +5v LEFT RIGHT STROBU GND JOYSTICK FWD BACK LEFT RIGHT +5v TRG1 TRG2 STROBU GND
   4	Рабочая температура	-10° C … +45° C
   5	Рабочая влажность	5 % … 95 %
   6	Температура хранения	-40° C … +60° C
   7	Влажность при хранении	5 % … 95 %
   8	Вес	126 г
   9	Переключатель	Tact switch x 2
   10	Разъем	D-Sub 9P (женский)
   11	Интерфейс	MSX
   12	Питание	+5v пост. тока
   13	Потребляемый ток	50mA макс.

Neos MS-10